Come eseguire il backup e ripristinare le impostazioni di visualizzazione delle cartelle in Windows 10

In Windows, puoi modificare la visualizzazione del modello, la larghezza delle colonne, il raggruppamento per , l'ordinamento per e il layout del contenuto della cartella nel modo desiderato.

Questo tutorial ti mostrerà come eseguire il backup e ripristinare le impostazioni di visualizzazione delle cartelle, i dettagli, la larghezza e le dimensioni del pannello di anteprima, la larghezza della finestra di navigazione, le finestre di dialogo Apri e Salva con nome per qualsiasi account in Windows 10 .

Ecco come:

1. Scaricare il file Backup_and_Restore_Folder_View_Settings_Tool.bat .

Nota :

Questo file .bat applicherà solo un backup e ripristinerà l'account corrente.

Di seguito sono riportati i contenuti di questo file .bat come riferimento:

Codice:

@ECHO OFF

Set "+=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
For /F "tokens=* " %%# in ('Reg Query "%+%" /V Desktop') Do (Set "#=%%#")
Set "#=%#:*REG_EXPAND_SZ    =%"
For /F "delims=" %%# in ('Echo "%#%"') Do (Set "#=%%#")
Set "[Desktop]=%#:~1,-1%"


title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice


:verify1
IF EXIST "%[Desktop]%\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice


:backup
mkdir "%[Desktop]%\Folder View Settings Backup"
REG EXPORT "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg" /y 
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%[Desktop]%\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice


:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" /F

REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg"

cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

2. Salvare il file .bat sul desktop.

3. Sblocca i file .bat.

4. Eseguire il file .bat.

5. Fai quello che vuoi fare nello strumento Impostazioni visualizzazione cartella di backup e ripristino .

Come eseguire il backup e ripristinare il layout del menu Start

BACKUP:

Quando crei un backup delle impostazioni di visualizzazione delle cartelle, la cartella Backup impostazioni di visualizzazione delle cartelle viene salvata sul desktop contenente i file .reg esportati dal registro per le impostazioni di visualizzazione delle cartelle. Puoi salvare questa cartella dove vuoi per sicurezza.

RISTABILIRE:

Quando desideri ripristinare un backup delle impostazioni di visualizzazione delle cartelle, devi prima avere una cartella di backup delle impostazioni di visualizzazione delle cartelle con questo nome esatto sul desktop per procedere con il processo di ripristino.

Come eseguire il backup e ripristinare le impostazioni di visualizzazione delle cartelle in Windows 10

Backup e ripristino delle impostazioni di visualizzazione delle cartelle in Windows 10

Spero che tu abbia successo.

Tags: #visualizzazione cartella #visualizzazione cartella win 10 #visualizzazione cartella di backup #visualizzazione cartella di ripristino

I migliori siti Web per apprendere abilità di hacking

Quando si parla di hacker, forse il primo stereotipo che immaginiamo è quello dello studente universitario o dell’esperto nel campo dell’informatica.

Come creare e utilizzare checkpoint Hyper-V in Windows 10

Checkpoint è una potente funzionalità di Hyper-V che semplifica l'annullamento di eventuali modifiche su una macchina virtuale.

3 strumenti per leggere gratuitamente le estensioni dei file DMG su PC Windows

Il formato file immagine DMG è il formato di archiviazione file più popolare utilizzato per distribuire software su Mac OS X. Questa estensione file non può essere letta sui computer PC Windows. Tuttavia, se desideri leggere questa estensione di file su un PC Windows, puoi chiedere il supporto di un'applicazione di terze parti.

Come aggiungere/rimuovere Accesso rapido nel riquadro di navigazione Esplora file su Windows 10

L'accesso rapido è il percorso più breve per raggiungere i file su cui stai lavorando e le cartelle che usi spesso. Queste sono le cartelle a cui accedi di frequente e i file recenti.

Recensione Opera VPN: semplice, veloce e gratuita

Forse hai sentito che il browser web Opera viene fornito con una VPN gratuita, o forse sei già un amante di Opera e vuoi semplicemente sapere come funziona il loro servizio VPN.

Come e perché dovresti disabilitare le reti Wi-Fi a 2,4 GHz?

Dovresti considerare di disattivare la vecchia banda da 2,4 GHz sulla tua rete Wi-Fi domestica e di utilizzare la nuova banda da 5 GHz, più veloce e meno "affollata". Scopriamolo attraverso il seguente articolo.

Come abilitare la funzionalità sandbox su Windows Defender

Il motore antivirus integrato di Microsoft Windows Defender è diventato il primo software antivirus in grado di funzionare in un ambiente sandbox.

Cosè il ransomware Screen Locker? Come rimuovere?

Screen Locker Ransomware è un tipo di ransomware che prende il controllo dello schermo e ti impedisce di utilizzare il tuo dispositivo. Questo tipo di ransomware è in aumento e può essere molto difficile da rimuovere senza informazioni sufficienti al riguardo.

6 motivi per cui la velocità del dongle WiFi è lenta e le prestazioni sono scarse

Quando utilizzi un dongle WiFi, potresti riscontrare alcuni problemi, in particolare velocità wireless scadenti che non soddisfano ciò di cui hai bisogno sugli altri dispositivi della tua casa. Ecco alcuni motivi per cui gli adattatori WiFi USB sono lenti e cosa puoi fare per risolverli.

Perché dobbiamo formattare lUSB? Come formattare lUSB?

Formattare un'unità USB è quasi come formattare qualsiasi altra unità. Puoi utilizzare le impostazioni predefinite o scoprire cosa significano le diverse opzioni e utilizzare quelle che funzionano meglio per te. Il seguente articolo ti aiuterà a scegliere le impostazioni ottimali durante la formattazione dell'USB.